Continuo la serie di post dedicati all’uso dell’RTC con integrato DS1307, in questa lezione viene suggerito come visualizzare su un display 16×2 Hitachi HD44780 1602 con modulo I2C PCF8574T: giorno della settimana, data e ora.
L’obiettivo che si vorrà raggiungere nei prossimi tutorial sarà quello di realizzare un timer programmabile da utilizzare in diverse esercitazioni di automazione.
Lo Schema di collegamento è il seguente:
Allego lo Sketch generale in cui ho inserito commenti di spiegazione sulle varie parti del codice e sull’utilizzo di specifiche funzioni.
Per quanto riguarda la libreria LiquidCrystal_I2C vi rimando alla lezione:
Utilizzo dell’LCD 16×2 Hitachi HD44780 1602 con modulo I2C PCF8574T
/* Prof. Maffucci Michele
15.01.2020
Orologio - v01
*/
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
// La data e l'ora funzionano usando un RTC DS1307 collegato tramite I2C e Wire lib
#include "RTClib.h"
RTC_DS1307 rtc;
char stringa1[8]; // per memorizzare la stringa che include la data (dimensione massima data: 8 caratteri)
char stringa2[6]; // per memorizzare la stringa che include l'ora (dimensione massima ora: 6 caratteri)
// Variabile per la verifica della cancellazione del display
int chiaveCancella = 0;
// Array multidimensionale costituito
// da 7 righe (giorni della settimana)
// 4 colonne (le lettere che compongono il giorno più il carattere null con cui deve terminare una stringa)
char giornoDellaSettimana[7][4] = {"Dom", "Lun", "Mar", "Mer", "Gio", "Ven", "Sab"};
// Inizializzazione della libreria in cui è descritta la modalità di utilizzo dei pin dell'LCD,
// impostazione dell'indirizzo dell'LCD 0x27 di 16 colonne e 2 linee
LiquidCrystal_I2C lcd(0x27, 16, 2);
void setup () {
lcd.begin(); // inizializzazione dell'LCD
lcd.backlight(); // attivazione della retroilluminazione
if (!rtc.isrunning()) {
lcd.setCursor(0, 0);
lcd.print("RTC non funzionante!");
// la riga che segue permette di impostare data e ora prendendo l'informazione
// dal computer a cui è collegato Arduino
rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
// la riga che segue permette di impostare
// esplicitamente da parte dell'utente data e ora
// Gennaio 21, 2014 alle 3 del pomeriggio ybisognrà scrivere:
// rtc.adjust(DateTime(2014, 1, 21, 3, 0, 0));
}
}
void loop () {
/* Controllo del funzionamento dell'RTC all'interno del loop
Il controllo della disconnessione dell'RTC viene effettuato anche all'interno del loop,
se ciò non venisse effettuato, una disconnessione dell'RTC non permetterebbe la visualizzazione
del messaggio "RTC non risponde", ma verrebbero visualizzati valori numerici errati.
La successiva connessione dell'RTC farà riapparire data e ora, ma in una modalità non allineata,
in cui saranno mostrati i valori numerici derivanti dalla precedente disconessione.
*/
if (!rtc.isrunning()) {
lcd.setCursor(0, 0);
lcd.print("RTC non risponde");
lcd.setCursor(0, 1);
lcd.print(" ");
chiaveCancella = 1;
}
else
{
if (chiaveCancella == 1) {
/* La cancellazione del display avviene solamente una sola volta, solo se si è verificata
una precedente disconnessione dell'RTC. L'azione è necessaria perché in fase
di riconnessione dell'RTC appaiono sul display numeri non coerenti.
La cancellazione potrebbe essere effettuata direttamente nel corpo della prima if,
ma ciò causerebbe un flikering del testo.
*/
lcd.clear();
chiaveCancella = 0;
}
DateTime now = rtc.now();
lcd.setCursor(0, 0);
// estrae dall'array giornoDellaSettimana il nome del giorno
lcd.print(giornoDellaSettimana[now.dayOfTheWeek()]);
lcd.setCursor(5, 0);
/*
int sprintf(char *str, const char *format, ...);
ha lo stesso funzionamento della printf, con la differenza che
l'output non sarà visualizzato sullo schermo (standard output), ma
immagazzinato nel vettore str
%d è uno dei possibili specificatori di formato che può essere usato nella sprintf
ha il compito di indicare alla funzione (la sprintf) il tipo della variabile che deve essere
visualizzata, in questo caso con d indichiamo decimale.
Con %02d si specifica la stampa di solo due numeri decimali.
*/
sprintf(stringa1, "%2d/%02d/%d", now.day(), now.month(), now.year());
lcd.print(stringa1);
lcd.setCursor(0, 1);
sprintf(stringa2, "%02d:%02d:%02d", now.hour(), now.minute(), now.second());
lcd.print(stringa2);
delay(1000);
}
}
Di seguito riprendo quanto già inserito nei commenti:
char giornoDellaSettimana[7][4] = {"Dom", "Lun", "Mar", "Mer", "Gio", "Ven", "Sab"};
Definisce un Array multidimensionale costituito da 7 righe, i giorni della settimana e 4 colonne, le lettere che compongono il giorno (3 lettere) più il carattere null con cui deve terminare una stringa.
...
if (!rtc.isrunning()) {
lcd.setCursor(0, 0);
lcd.print("RTC non risponde");
lcd.setCursor(0, 1);
lcd.print(" ");
chiaveCancella = 1;
}
...
Il controllo della disconnessione dell’RTC viene effettuato anche all’interno del loop, se ciò non venisse eseguito, una disconnessione dell’RTC non permetterebbe la visualizzazione del messaggio “RTC non risponde”, ma verrebbero mostrati valori numerici errati. La successiva connessione dell’RTC farà riapparire data e ora, ma in una modalità non allineata, in cui saranno mostrati i valori numerici derivanti dalla precedente disconessione.
...
else
{
if (chiaveCancella == 1) {
/* La cancellazione del display avviene solamente una sola volta, solo se si è verificata
una precedente disconnessione dell'RTC. L'azione è necessaria perché in fase
di riconnessione dell'RTC appaiono sul display numeri non coerenti.
La cancellazione potrebbe essere effettuata direttamente nel corpo della prima if,
ma ciò causerebbe un flikering del testo.
*/
lcd.clear();
chiaveCancella = 0;
}
...
La cancellazione del display avviene una sola volta, solo se si è verificata una precedente disconnessione dell’RTC. L’azione è necessaria perché in fase di riconnessione dell’RTC appaiono sul display numeri non coerenti. La cancellazione potrebbe essere effettuata direttamente nel corpo della prima if, ma ciò causerebbe un flikering del testo così come appare nell’immagine che segue:
sprintf(stringa1, "%2d/%02d/%d", now.day(), now.month(), now.year());
int sprintf(char *str, const char *format, …); ha lo stesso funzionamento della printf, con la differenza che l’output non sarà visualizzato sullo schermo (standard output), ma immagazzinato nel vettore str.
%d è uno dei possibili specificatori di formato che può essere usato nella sprintf ha il compito di indicare alla funzione (la sprintf) il tipo della variabile che deve essere visualizzata, in questo caso con d indichiamo decimale. Con %02d si specifica la stampa di solo due numeri decimali.
Per i miei allievi:
Esercizio 1
Modificare lo sketch proposto in modo che la retroilluminazione dello schermo venga spenta dopo 15 secondi e la pressione di un pulsante la riattivi.
Esercizio 2
Modificare lo sketch realizzato al punto 2 inserendo anche un sensore DHT11 che mostra temperatura ed umidità dell’ambiente.
In riferimento a quanto esposto a lezione questa mattina durante la lezione a distanza, aggiungo alcune indicazioni per disegnare icone personalizzate sul display: pacman, alieno, fantasmi, ecc… La modalità di realizzazione icone è la medesima di quella spiegata nella lezione svolta alcuni mesi fa: 
